1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
#! ./spec/dzref
nl‿tab←•UCS 10‿9
charSet←∾charGroups←⟨
chF←"+-×÷⋆√⌊⌈|¬∧∨<>≠=≤≥≡≢⊣⊢⥊∾≍↑↓↕⌽⍉/⍋⍒⊏⊑⊐⊒∊⍷⊔" # Function
"˜˘¨⌜⁼´`" # Modifier
"∘○⊸⟜⌾⊘◶⎉⚇⍟" # Composition
¯1⊏˘10‿2⥊"𝕨𝕎𝕩𝕏𝕗𝔽𝕘𝔾𝕤𝕊" # Input (𝕣 pending; ℝ not allowed)
nl∾"⋄," # Separator
"←↩→" # Gets
"(){}⟨⟩" # Bracket
"‿" # Ligature
•d # +⟜(↕10)⌾•UCS'0' # Digit
"¯.π∞" # Numeric
"_"∾' '(⊢∾+)⌾•UCS•a # Alphabetic
1↑"𝕨" # Prefix for input (hack around UTF-16)
" "∾tab # Whitespace
# #'" eliminated during tokenization
⟩
bF‿bM‿bC‿bI‿bS‿bG‿bB‿bL‿bD‿bN‿bA‿bP‿bW←⊔/≠¨charGroups
vi←+´≠¨8↑charGroups
Tokenize←{
r←𝕩='#'⋄s←/(≠↑2⊸↓)⊸∧𝕩=⊑"'"⋄d←/𝕩='"'
g←⍋q←∾⟨ s⋄¯1↓d⋄/r⟩ ⋄q↩g⊏q
e← g⊏∾⟨2+s⋄ 1↓d⋄(⊢-¯1↓0∾⊢)∘⊏⟜(0∾+`r)⊸//(𝕩=nl)∾1⟩
Se←{(⊏˜𝕨)Se 1¨⌾((𝕩/𝕨)⊸⊏)𝕩}⍟{0=⊑⌽𝕩}
st←¯1↓Se⟜(1↑˜≠)∾⟜≠q⊸⍋¨e⋄b←st/q∾˘e
ToI←¯1↓·/⁼(≠𝕩)∾˜⥊⋄f←¬≠`ToI b
cb←(¬(st/q)⊏r)/b
nl←≠lu←⍷lit←𝕩⊔˜1-˜(+`ToI⊑˘cb)×≠`ToI cb
cl←f/ToI⊑∘⌽˘cb
args←charSet⊸⊐¨𝕨⋄c←charSet⊐f/𝕩
w←(≠↑0∾⊢)⊸<l←c∊∾bD‿bN‿bA
id←⍷args∾(bA∊˜w/c)⍒⊸⊏i←(1-˜l×+`w)⊔c
nv←+´bA∊˜⊑¨id
c↩(w∨¬l∨c∊bP∾bW)/(vi+id⊐i)⌾(w⊸/)(vi+(≠id)+lu⊐lit)⌾(cl⊸/)c
c/˜↩¬(1⌾⊑1⌽1⌾⊑)⊸∧c∊bS
⟨c,nv,nv-≠args,(nv↓id)∾lu⟩
}
Parse←{
a←𝕩∊(2↑bG)⋄at←1⌽a⋄𝕩/˜↩¬a⋄a/˜↩¬at
l←≠𝕩⋄sep←𝕩∊bS⋄𝕩↩(bF⊑˜⥊chF⊐<'⊣')¨⌾(sep⊸/)𝕩⋄sep∨↩𝕩=2⊑bB
o←𝕩=0⊑bB⋄c←𝕩=1⊑bB⋄v←a-˜𝕩≥vi⋄f←¬o∨c∨v∨sep
na←(2×sep)+f×1+l↑0∾c∨v
d←+`o-c⋄fe←(d⍋⊸(⍋∘⊣⊏+`∘⊏)o)⊏l∾(⍋⊏⟜d)⊸⊏/c
fe⌊↩l-l↑⌽⌈`↕∘≠⊸×⌽1∾˜sep
sel←¬∘⊏⟜(o∨c)⊸/⍋((f×fe)⌈↕l)-+`f-l↑/⁼∧f/fe
sel⊸⊏¨𝕩‿na
}
Base←{+⟜(𝕨⊸×)´𝕩}
Enc2←{2|⌊∘÷⟜2⍟(↕𝕨)𝕩}
Hex←16 Base⟜⌽ (•d∾"ABCDEF")⊸⊐
ReadNum←10 Base⟜⌽ bD⊸⊐
GenF64←{
0:8⥊0;
l←2(⌊⋆⁼)𝕩
(Hex"44")∾2 Base˘8‿8⥊∾⟨¯52↑(0⌈l)Enc2𝕩,11 Enc2 1023+l,⥊0⟩
}
MakeTab←{{⊑∘(∾⟜0)¨¯1↓(chF⊐𝕨)⊔○(∾⟜(≠chF))𝕩}○∾⟜(⥊¨∘⥊¨)´<˘⍉(2(÷˜∾⊣)≢)⊸⥊𝕩}
tab1←MakeTab⟨
"⊣⊢" , 2⥊<⟨⟩
"|-⌈⌊√" , (Hex"99")+(↕4)∾6
"÷" , <(Hex"10")∾0
"¬" , <∾⥊¨⟨Hex"9A",GenF64 1,Hex"A0"⟩
⟩
tab2←MakeTab⟨
"⊣" , Hex"1A"
"+-×÷⌊⌈∧", (Hex"A0")+(↕6)∾2
"¬" , <∾⥊¨⟨Hex"A1",GenF64 1,Hex"A0"⟩
"∨" , <(Hex"10")∾1
⟩
fntab←⍉(0¨tab1)∾tab1≍tab2
f64←127-3
GenFn←{
⟨⟩GenFn𝕩;
⟨t,nVar,nLoc,lits⟩←𝕨Tokenize𝕩
t⊏˜↩⍋+`-´<˘(2‿3⊏bB)=⌜t
nd←+´c←t=3⊑bB
t↩((vi+nVar+≠lits)+↕∘≠)⌾(c⊸/)t
⟨a,na⟩←Parse t
ops←⥊∾⟨
∾⟜(0⥊˜3∾˜vi-≠)fntab
⍉(Hex¨"20"‿"22"‿"21")∾⌜↕nVar
⊣⌜⟜(↕3)(GenF64∘ReadNum¨lits)∾(Hex"10")∾¨3+↕nd
⟩
(((≠∾∾)⟨nLoc∾f64⟩)∾(Hex"0B")∾˜∾)¨((⊢-˜¬×+`)a=2⊑bB)⊔(na+3×a)⊏ops
}
Gen←{
LEB←{0:⥊0;128⊸+⌾(¯1⊸↓) 2 Base˘ (⌽·∨`·⌽∨´˘)⊸/ 10‿7(⊣⥊×´⊸↑) 64 Enc2 𝕩}
C←LEB∘≠⊸∾
S←∾⟜C
V←≠∾∾
I←C∘•UCS
t‿n‿b←𝕩
∾⟨
0∾(•UCS"asm")∾4↑1
1 S V (96∾⟜∾C¨)¨t
3 S V ⥊¨↕≠b
7 S V ⥊<"fn"I⊸(⊣∾0∾⊢)n
10 S V C¨ b
⟩
}
rcp←⟨"x"⟩ GenFn "1÷x"
or←⟨"w","x"⟩ GenFn "(w+x)-w∧x"
Compile←{
body←GenFn 𝕩
f←⟨rcp,or,body⟩
Gen ⟨(≠¨f)/(1‿2‿0∾¨1)⥊¨¨f64 ⋄ 2 ⋄ ∾f⟩
}
# Targetting dzaima/BQN bytecode:
DParse ← {
l←≠𝕩⋄sep←𝕩∊bS⋄𝕩↩(⌽⍋⍋⌽+`(≠↑0∾⊢)⊸∨sep)⊏𝕩
a←𝕩∊2↑bG⋄o←𝕩=1⊑bB⋄c←𝕩=0⊑bB⋄v←𝕩≥vi⋄f←𝕩∊bF
d←+`o-c⋄fe←(d⍋⊸(⍋∘⊣⊏+`∘⊏)o)⊏l∾(⍋⊏⟜d)⊸⊏/c
dy←1↓0∾˜o∨v⋄la←(¯1⌽f×dy)/(o×fe)⌈↕l⋄mc←/f׬dy
n←𝕩≥vi+𝕨⋄id←/v-n⋄cn←/f∨n⋄s←/sep⋄u←⍷ob←cn⊏𝕩
bc←(⍋(∾˜cn∾id)∾(1+/a)∾s∾mc∾la)⊏∾⟨0¨cn,(1+(id-1)⊏a),u⊐ob,vi-˜id⊏𝕩,(11-⊑bG)+a/𝕩,14¨s,5¨mc,6¨la⟩
bc‿u
}
prims←⟨
+,-,×,÷,⋆,√,⌊,⌈,|,¬,∧,∨,<,>,≠,=,≤,≥,≡,≢,⊣,⊢,⥊,∾,≍,↑,↓,↕,⌽,⍉,/,⍋,⍒,⊏,⊑,⊐,⊒,∊,⍷,⊔
˜,˘,¨,⌜,⁼,´,`
∘,○,⊸,⟜,⌾,⊘,◶,⎉,⚇,⍟
⟩
DGenFn←{
⟨t,nVar,nLoc,lits⟩←⟨⟩Tokenize𝕩
⟨bc,u⟩←nVar DParse t
o←(u-(vi+nVar-≠prims)×u≥vi)⊏prims∾ReadNum¨lits
⟨bc,o,nVar↑•a,⟨⟩⟩
}
DRun←{
('f'‿0 •COMP DGenFn 𝕩){𝔽} 0
}
|
